***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Dec 08, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt TS240S DC+ AC1 AC2 DC-
.param
+ vc0 = 6.398e-1
+ vc1 = 5.634e-2
+ vc2 = 3.658e-3
+ tc1 = 1.441e-1
+ tc2 = 4.256e-2
g12 DC+ AC1 value={(vc0+vc1*v(DC+,AC1)+vc2*v(DC+,AC1)*v(DC+,AC1))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d12 AC1 DC+ diode
g13 DC+ AC2 value={(vc0+vc1*v(DC+,AC2)+vc2*v(DC+,AC2)*v(DC+,AC2))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d13 AC2 DC+ diode
g24 AC1 DC- value={(vc0+vc1*v(AC1,DC-)+vc2*v(AC1,DC-)*v(AC1,DC-))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d24 DC- AC1 diode
g34 AC2 DC- value={(vc0+vc1*v(AC2,DC-)+vc2*v(AC2,DC-)*v(AC2,DC-))*1e-6*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))}
d34 DC- AC2 diode
.model diode d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 0.1e-3
+ is = 4.691e-7
+  n = 1.028                     
+ rs = 3.553e-2     
+ikf = 2
+ bv = 44                       
***** capacitance parameter ***
+cjo = 4.763e-10  
+  m = 4.439e-1
+ vj = 5.352e-1 
+ fc = 0.5   
***** temperature coefficient ***
+tnom = 25                     
+  eg = 7.051e-1   
+ xti = 3             
+trs1 = 5.972e-3     
+trs2 = -1.513e-5         
+tikf = -5e-3
.ends TS240S
*$
